OperationInterface.idl

Go to the documentation of this file.

#ifndef ORO_CORBA_OPERATION_REPOSITORY_IDL
#define ORO_CORBA_OPERATION_REPOSITORY_IDL

#ifdef CORBA_IS_TAO
//resolves LNK2005
#include <tao/orb.idl>
#endif

module RTT
{
  module corba
  {
    typedef sequence<any> CAnyArguments;

    struct CArgumentDescription
    {
      string name;        
      string description; 
      string type;        
    };

    typedef sequence<CArgumentDescription> CArgumentDescriptions;

    typedef sequence<string> CTypeList;

    struct COperation
    {
      string name;
      string description;
      CArgumentDescriptions arguments;
      CTypeList collect_types;
      string result_type;
      boolean send_oneway;
    };

    exception CWrongArgumentException
    {
      long which_arg;
      long max_arg;
    };

    exception CWrongNumbArgException
    {
      long wanted;
      long received;
    };

    exception CWrongTypeArgException
    {
      long whicharg;
      string expected;
      string received;
    };

    exception CNoSuchNameException
    {
      string name;
    };
    
    enum CSendStatus { CCollectFailure, CSendFailure, CSendNotReady, CSendSuccess };

    exception CCallInterrupted
    {
    };

    exception CCallError
    {
      string what;
    };
    
    interface CSendHandle {
    
        CSendStatus collect(out CAnyArguments args) raises(CCallError);

        CSendStatus collectIfDone(out CAnyArguments args) raises(CCallError);
        
        CSendStatus checkStatus();
        any ret() raises(CCallError);                       

      void checkArguments(in CAnyArguments args) raises (
                                 CWrongNumbArgException,
                                 CWrongTypeArgException);

      void dispose();
    };

    interface COperationInterface
    {
      typedef sequence<COperation> COperationDescriptions;

      COperationDescriptions getOperations();

      CArgumentDescriptions getArguments(in string operation) raises (CNoSuchNameException);

      unsigned short getArity(in string operation) raises (CNoSuchNameException);

      unsigned short getCollectArity(in string operation) raises (CNoSuchNameException);

      string getResultType(in string operation) raises (CNoSuchNameException);
      
      string getArgumentType(in string operation, in unsigned short nbr) raises (CNoSuchNameException, CWrongArgumentException);
      
      string getCollectType(in string operation, in unsigned short nbr) raises (CNoSuchNameException, CWrongArgumentException);

      string getDescription(in string operation) raises (CNoSuchNameException);

      void checkOperation(in string operation, in CAnyArguments args) raises ( CNoSuchNameException,
                                 CWrongNumbArgException,
                                 CWrongTypeArgException);

      any callOperation(in string operation, inout CAnyArguments args) raises ( CNoSuchNameException,
                                 CWrongNumbArgException,
                                 CWrongTypeArgException,
                                 CCallInterrupted,
                                 CCallError);

      CSendHandle sendOperation(in string operation, in CAnyArguments args) raises ( CNoSuchNameException,
                                 CWrongNumbArgException,
                                 CWrongTypeArgException,
                                 CCallInterrupted);

      oneway void sendOperationOneway(in string operation, in CAnyArguments args);

    };

  };
};
#endif